VmAbortReporter

class NAMESPACE_VmAbortHandler : EventHandler
{
  override void playerSpawned(PlayerEvent event)
  {
    mReport = new("NAMESPACE_Report");
    if (event.playerNumber == consolePlayer) mReport.writePlayerInfo();
  }

  override void uiTick()
  {
    bool isOnceASecond = level.totalTime % TICRATE == 0;
    if (isOnceASecond) mReport.writeSystemTime();
  }

  override void onDestroy()
  {
    if (gameState != GS_FullConsole
        || !amIFirst()
        || !Cvar.getCvar("NAMESPACE_vm_abort_report_enabled", players[consolePlayer]).getBool())
      {
        return;
      }

    Console.printf("%s\n%s", mReport.report(), getAttentionMessage());
  }

  override void consoleProcess(ConsoleEvent event)
  {
    if (amIFirst() && event.name == "NAMESPACE_report")
      {
        Console.printf("%s", mReport.report());
      }
  }

  private clearscope bool amIFirst()
  {
    foreach (aClass : AllClasses)
    {
      string className = aClass.getClassName();
      bool isVmAbortHandler = (className.indexOf("VmAbortHandler") != -1);

      if (!isVmAbortHandler) continue;

      return className == getClassName();
    }
    return false;
  }

  private clearscope string getAttentionMessage()
  {
    string userName = players[consolePlayer].getUserName();
    string hashes = "\cg############################################################";

    Array<string> lines =
      {
        "",
        hashes,
        " " .. userName .. "\cg, please report this VM abort to mod author.",
        " Attach screenshot to the report.",
        " Type \"screenshot\" below to take a screenshot.",
        hashes
      };

    return NAMESPACE_su.join(lines, "\n");
  }

  private NAMESPACE_Report mReport;
}

class NAMESPACE_Report
{
  clearscope void writePlayerInfo()
  {
    mPlayerClassName = players[consolePlayer].mo.getClassName();
    mSkillName       = g_SkillName();
  }

  ui void writeSystemTime()
  {
    mSystemTime = SystemTime.now();
  }

  clearscope string report()
  {
    Array<string> lines =
      {
        getSystemTime(),
        getGameInfo(),
        getConfiguration(),
        getEventHandlers()
      };

    return NAMESPACE_su.join(lines, "\n");
  }

  private static clearscope string getConfiguration()
  {
    return new("NAMESPACE_Description")
      .addCvar("compatflags")
      .addCvar("compatflags2")
      .addCvar("dmflags")
      .addCvar("dmflags2")
      .addCvar("autoaim").compose();
  }

  private clearscope string getGameInfo()
  {
    return new("NAMESPACE_Description")
      .add("level", level.mapName)
      .addInt("time", level.totalTime)
      .addBool("multiplayer", multiplayer)
      .add("player class", mPlayerClassName)
      .add("skill", mSkillName).compose();
  }

  private static clearscope string getEventHandlers()
  {
    Array<string> normalEventHandlers;
    Array<string> staticEventHandlers;

    foreach (aClass : AllClasses)
    {
      if (!(aClass is "StaticEventHandler")) continue;
      if (aClass == "StaticEventHandler" || aClass == "EventHandler") continue;

      if (aClass is "EventHandler") normalEventHandlers.push(aClass.getClassName());
      else staticEventHandlers.push(aClass.getClassName());
    }

    return "Event handlers: " .. NAMESPACE_su.join(normalEventHandlers) .. "\n" ..
      "Static event handlers: " .. NAMESPACE_su.join(staticEventHandlers);
  }

  private clearscope string getSystemTime()
  {
    return "System time: " .. SystemTime.format("%F %T %Z", mSystemTime);
  }

  private string mPlayerClassName;
  private string mSkillName;
  private int mSystemTime;
}